Navigae SPARQL End Point

Principios

Acceso al Navigae GeoSPARQL

El SPARQL endpoint permite interrogar los datos estructurados al formato RDF presentes sobre la plataforma Navigae.
Acceder al Navigae GeoSPARQL

Acceso remoto al punto final SPARQL

Para acceder al punto final de SPARQL Navigae desde otro entorno remoto, la URL del repositorio es: https://www.navigae.fr/graphdb/repositories/Navigae

La ontología Navigae

La ontología Navigae es una representación de los conocimientos presentes en la plataforma Navigae y se construye sobre el modelo de datos de RDF.

GeoSPARQL

Los datos de Navigae están representados según el modelo GeoSPARQL.
GeoSPARQL es una representación e interrogación estándar de datos geoespaciales relacionados para la Web Semántica definida por Open Geospatial Consortium (OGC).
Lo que sigue es un diagrama simplificado de las clases de Geometría y Característica de GeoSPARQL, así como de algunas de sus propiedades :

Ejemplos de consultas SPARQL

Recuperar los datos de Navigae

Escribir una búsqueda simple para obtener todas las mapas o fotografías presentes :

PREFIX nav: <https://www.navigae.fr/ontology#>
SELECT * WHERE {
  { ?s a nav:GeolocatedData. }
}  
LIMIT 10

Prueba

Recuperar los objetos más próximos

Encontrar los 3 objetos más próximos de la foto de identificador https://hdl.handle.net/20.500.12187/508c8f3a-b820-36ed-bc65-9a07cff4d8c6 localizada en 44.270778656006, 71.30451965332 :

PREFIX uom: <http://www.opengis.net/def/uom/OGC/1.0/>
PREFIX nav: <https://www.navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fWKT ?cWKT ?d
WHERE {
    <https://hdl.handle.net/20.500.12187/508c8f3a-b820-36ed-bc65-9a07cff4d8c6> nav:hasPointGeometry ?cGeom .
    ?cGeom geo:asWKT ?cWKT .
    ?f nav:hasPointGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (?fGeom != ?cGeom)
    BIND(geof:distance(?cWKT, ?fWKT, uom:metre) AS ?d)
}
ORDER BY ASC(?d)
LIMIT 3

Prueba

Recuperar puntos incluidos en un área predefinida

Obtener todos los puntos situados en una zona dibujada en los alrededores de Bamako.

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fGeom ?fWKT
WHERE {
    ?f nav:hasPointGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (geof:sfWithin(?fWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
}

Prueba

Recuperar los polígonos incluidos en un área predefinida

Obtener todos los polígonos situados en una zona dibujada en los alrededores de Bamako.

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fGeom ?fWKT
WHERE {
    ?f nav:hasPolygonGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (geof:sfWithin(?fWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
}

Prueba

Construir una zona calculada en las coordenadas de los objetos

Calcula el cuadro de límite mínimo entre este Reunión y esta foto de la Llanura Imbo (Burundi) :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>
PREFIX uom: <http://www.opengis.net/def/uom/OGC/1.0/>

SELECT *
WHERE {
    <https://hdl.handle.net/20.500.12187/7e1a948f-47ce-369a-90c0-89c8052c831d> nav:hasPointGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT .
    <https://hdl.handle.net/20.500.12187/dd58afad-710d-3c27-8f43-c1ebe9b7d8b4> nav:hasPointGeometry ?bGeom .
    ?bGeom geo:asWKT ?bWKT .
    BIND (geof:envelope(geof:union(?aWKT, ?bWKT)) AS ?envelope) 
}

Prueba

Detectar áreas de superposición

Identificar todos los objetos que superponen el mapa del departamento de Antoquia en Colombia :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fWKT ?a
WHERE {
    <https://hdl.handle.net/20.500.12187/3c58789b-f3b9-3af4-90b5-60831d1b6ef6> nav:hasPolygonGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT.
    ?f nav:hasPolygonGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT.
    FILTER (geof:sfOverlaps(?fWKT, ?aWKT)).
}

Prueba

Detectar las zonas distintas

Identificar 2 objetos geométricos que cubren la misma zona sin se superponer :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT *
WHERE {
    ?a nav:hasPolygonGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT .
    ?b nav:hasPolygonGeometry ?bGeom .
    ?bGeom geo:asWKT ?bWKT .
    FILTER (geof:sfWithin(?aWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
  FILTER (geof:sfWithin(?bWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
   FILTER(?a != ?b)
   FILTER (geof:ehDisjoint(?aWKT, ?bWKT))
}
LIMIT 1

Prueba